Saya memiliki lembar kerja Excel di mana saya menuliskan semua jam per hari saya mengerjakan proyek saya. Selama satu hari saya hanya bekerja beberapa menit di sana-sini.

Dalam satu kolom lembar saya, saya ingin akumulasi / penambahan jam saya bekerja pada hari itu.

Jadi setelah baris dengan day, start, dan end selesai, accumulated hours per day perujuk untuk baris baru ini akan muncul. Saya ingin sel ini terisi sebelumnya, sehingga saya tidak perlu melakukan penyesuaian manual apa pun dari isi sel ini.

Bagaimana rumus di kolom accumulated hours per day harus terlihat untuk mencapai ini?

I need a formula for the rightmost column

0
user14175128 13 Mei 2021, 07:08

3 jawaban

Jawaban Terbaik

Anda sedang mencari ini:

=IF(A2<>A1,0,D1)+C2-B2

Idealnya, saya sarankan menghindari referensi di baris atas dengan menggunakan OFFSET. Coba ini sebagai gantinya:

=IF(A2<>OFFSET(A2,-1,0),0,OFFSET(D2,-1,0))+C2-B2
2
Enigmativity 13 Mei 2021, 04:19

Anda juga dapat mencoba versi rumus array:

=SUBTOTAL(9,OFFSET(C2,0,0,ROW(A2:A9)-1))-IFERROR(SUBTOTAL(9,OFFSET(C2,0,0,MATCH(A2:A9,A2:A9,0)-1)),0)-
(SUBTOTAL(9,OFFSET(B2,0,0,ROW(A2:A9)-1))-IFERROR(SUBTOTAL(9,OFFSET(B2,0,0,MATCH(A2:A9,A2:A9,0)-1)),0))

Atau lebih dinamis menggunakan Excel 365 Let and Sequence:

=LET(range,A2:INDEX(A:A,COUNTA(A:A)),r,ROWS(range),
SUBTOTAL(9,OFFSET(C2,0,0,SEQUENCE(r)))-IFERROR(SUBTOTAL(9,OFFSET(C2,0,0,MATCH(range,range,0)-1)),0)-
(SUBTOTAL(9,OFFSET(B2,0,0,SEQUENCE(r)))-IFERROR(SUBTOTAL(9,OFFSET(B2,0,0,MATCH(range,range,0)-1)),0)
))

enter image description here

0
Tom Sharpe 13 Mei 2021, 13:45

Saya menyarankan untuk membuat tabel pivot dan di sana Anda dapat melakukan banyak hal.

Pivot table

0
user7394563 13 Mei 2021, 06:37